FunctX XQuery Function Library > Sequences > Distinct Values >

functx:distinct-nodes

The distinct XML nodes in a sequence (by node identity)

Description

The functx:distinct-nodes function returns the distinct nodes (based on node identity) in a sequence. It does this without resorting them in document order (it takes the first occurrence of each distinct node).It is different from the built-in fn:distinct-values function in that it returns nodes rather than atomic values, and it does not take into account the values (content) of the nodes, just their identity.

Note: if you want them to be resorted in document order, or you don't care, you can simply use the expression "$nodes/." (without the quotes), which works because the slash operator removes duplicates and resorts. The "." in the expression returns the node itself.

Arguments and Return Type

XQuery Function Declaration

declare namespace functx = "http://www.functx.com"; 
declare function functx:distinct-nodes 
  ( $nodes as node()* )  as node()* {
       
    for $seq in (1 to count($nodes))
    return $nodes[$seq][not(functx:is-node-in-sequence(
                                .,$nodes[position() < $seq]))]
 } ;

declare namespace functx = "http://www.functx.com" 
define function distinct-nodes 
  ( $nodes as node()* )  as node()* {
       
    for $seq in (1 to fn:count($nodes))
    return $nodes[$seq][fn:not(functx:is-node-in-sequence(
                                .,$nodes[fn:position() < $seq]))]
 }

Examples

<test>
  <child>1</child>
  <child>2</child>
  <child>3</child>
  <child>3</child>
</test>

functx:distinct-nodes(
     ($in-xml/child, $in-xml/*) )

<child>1</child>
<child>2</child>
<child>3</child>
<child>3</child>

functx:distinct-nodes(
     ($in-xml/child[3], $in-xml/*) )

<child>3</child>
<child>1</child>
<child>2</child>
<child>3</child>

Depends On

See Also

History